home *** CD-ROM | disk | FTP | other *** search
/ Amiga Format CD 52 / Amiga Format AFCD52 (Issue 136, May 2000).iso / -serious- / programming / other / dopus412-gpl / library / functions.a < prev    next >
Text File  |  2000-02-28  |  9KB  |  553 lines
  1. ; Directory Opus 4
  2. ; Original GPL release version 4.12
  3. ; Copyright 1993-2000 Jonathan Potter
  4. ; 
  5. ; This program is free software; you can redistribute it and/or
  6. ; modify it under the terms of the GNU General Public License
  7. ; as published by the Free Software Foundation; either version 2
  8. ; of the License, or (at your option) any later version.
  9. ; 
  10. ; This program is distributed in the hope that it will be useful,
  11. ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13. ; GNU General Public License for more details.
  14. ; 
  15. ; You should have received a copy of the GNU General Public License
  16. ; along with this program; if not, write to the Free Software
  17. ; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  18. ; 
  19. ; All users of Directory Opus 4 (including versions distributed
  20. ; under the GPL) are entitled to upgrade to the latest version of
  21. ; Directory Opus version 5 at a reduced price. Please see
  22. ; http://www.gpsoft.com.au for more information.
  23. ; 
  24. ; The release of Directory Opus 4 under the GPL in NO WAY affects
  25. ; the existing commercial status of Directory Opus 5.
  26.  
  27.  
  28.     SECTION    code
  29.  
  30.     INCLUDE "exec/types.i"
  31.     INCLUDE "exec/initializers.i"
  32.     INCLUDE "exec/libraries.i"
  33.     INCLUDE "exec/lists.i"
  34.     INCLUDE "exec/alerts.i"
  35.     INCLUDE "exec/resident.i"
  36.     INCLUDE "exec/ports.i"
  37.     INCLUDE "exec/io.i"
  38.     INCLUDE "libraries/dos.i"
  39.     INCLUDE "graphics/rastport.i"
  40.  
  41.     INCLUDE "asmsupp.i"
  42.     INCLUDE "dopusbase.i"
  43.  
  44.     XREF _IntuitionBase
  45.     XREF _GfxBase
  46.  
  47.     XDEF endcode
  48.     XDEF GetWBScreen
  49.     XDEF Seed
  50.     XDEF Random
  51.     XDEF StrToUpper
  52.     XDEF StrToLower
  53.     XDEF DisableGadget
  54.     XDEF EnableGadget
  55.     XDEF GhostGadget
  56.     XDEF _SwapMem
  57.     XDEF _LSprintf
  58.     XDEF LSprintf
  59.     XDEF LCreateExtIO
  60.     XDEF LCreatePort
  61.     XDEF LDeleteExtIO
  62.     XDEF LDeletePort
  63.     XDEF LToUpper
  64.     XDEF LToLower
  65.     XDEF LStrCat
  66.     XDEF LStrnCat
  67.     XDEF LStrCpy
  68.     XDEF LStrnCpy
  69.     XDEF LStrCmpI
  70.     XDEF LStrnCmpI
  71.     XDEF LStrCmp
  72.     XDEF LStrnCmp
  73.  
  74.     
  75. wbname
  76.     dc.b 'Workbench',0
  77. rand
  78.     ds.l 2
  79. ditherdata
  80.     dc.w $8888,$2222
  81.  
  82. GetWBScreen:
  83.     movem.l a2/a3/a5/a6,-(sp)
  84.     move.l _IntuitionBase,a6
  85.     move.w 20(a6),d0
  86.     cmp.w #36,d0
  87.     blt getwb13
  88.     move.l a0,a2
  89.     lea wbname(pc),a0
  90.     jsr _LVOLockPubScreen(a6)
  91.     move.l d0,a3
  92.     move.l d0,a0
  93.     move.l a2,a1
  94.     move.l #346,d0
  95.     move.l 4,a6
  96.     jsr _LVOCopyMem(a6)
  97.     move.l a5,a6
  98.     move.l #0,a0
  99.     move.l a3,a1
  100.     move.l _IntuitionBase,a6
  101.     jsr _LVOUnlockPubScreen(a6)
  102.     bra endgetscr
  103. getwb13:
  104.     move.l #346,d0
  105.     moveq.l #1,d1
  106.     move.l #0,a1
  107.     jsr _LVOGetScreenData(a6)
  108. endgetscr:
  109.     movem.l (sp)+,a2/a3/a5/a6
  110.     rts
  111.  
  112. Seed:
  113.     move.l d0,d1
  114.     not.l d1
  115.     movem.l d0/d1,rand
  116. longrnd:
  117.   movem.l d2-d3,-(sp) 
  118.     movem.l rand,d0/d1
  119.     andi.b #$0e,d0
  120.     ori.b #$20,d0
  121.     move.l d0,d2
  122.     move.l d1,d3
  123.     add.l d2,d2 
  124.     addx.l d3,d3
  125.     add.l d2,d0
  126.     addx.l d3,d1
  127.     swap d3
  128.     swap d2
  129.     move.w d2,d3
  130.     clr.w d2
  131.     add.l d2,d0
  132.     addx.l d3,d1
  133.     movem.l d0/d1,rand
  134.     move.l d1,d0
  135.     movem.l (sp)+,d2-d3
  136.     rts
  137.  
  138. Random:
  139.     move.w d2,-(sp)
  140.     move.w d0,d2
  141.     beq.s skip
  142.     bsr.s longrnd
  143.     clr.w d0
  144.     swap d0
  145.     divu.w d2,d0
  146.     clr.w d0
  147.     swap d0
  148. skip:
  149.     move.w (sp)+,d2
  150.     rts
  151.  
  152. StrToUpper:
  153.     move.b (a0)+,d0
  154.     bsr LToUpper
  155.     move.b d0,(a1)+
  156.     bne.s StrToUpper
  157.     rts
  158.  
  159. StrToLower:
  160.     move.b (a0)+,d0
  161.     bsr LToLower
  162.     move.b d0,(a1)+
  163.     bne.s StrToLower
  164.     rts
  165.  
  166. DisableGadget:
  167.     btst.b #0,12(a0)
  168.     bne disabled
  169.     bset.b #0,12(a0)
  170.     bsr GhostGadget
  171. disabled:
  172.     rts
  173.  
  174. EnableGadget:
  175.     btst.b #0,12(a0)
  176.     beq enabled
  177.     bclr.b #0,12(a0)
  178.     bsr GhostGadget
  179. enabled:
  180.     rts
  181.  
  182. GhostGadget:
  183.     movem.l a2/a3/a6/d2-d5,-(sp)
  184.     move.b 28(a1),-(sp)
  185.     move.l a0,a2
  186.     move.l a1,a3
  187.     move.l d0,d4
  188.     move.l d1,d5
  189.  
  190.     moveq.l #2,d0    
  191.     move.l db_GfxBase(a6),a6
  192.     jsr _LVOSetDrMd(a6)
  193.  
  194.     move.l a3,a1    
  195.     lea ditherdata(pc),a0
  196.     move.l a0,8(a1)
  197.     move.b #1,29(a1)
  198.  
  199.     move.l d4,d0
  200.     add.w 4(a2),d0
  201.     move.l d5,d1
  202.     add.w 6(a2),d1
  203.     moveq.l #0,d2
  204.     move.w 4(a2),d2
  205.     add.w 8(a2),d2
  206.     subq.l #1,d2
  207.     sub.l d4,d2
  208.     moveq.l #0,d3
  209.     move.w 6(a2),d3
  210.     add.w 10(a2),d3
  211.     subq.l #1,d3
  212.     sub.l d5,d3
  213.     jsr _LVORectFill(a6)
  214.  
  215.     move.l a3,a1    
  216.     move.l #0,8(a1)
  217.     move.b #0,29(a1)
  218.  
  219.     moveq.l #0,d0
  220.     move.b (sp)+,d0
  221.     jsr _LVOSetDrMd(a6)
  222.     movem.l (sp)+,a2/a3/a6/d2-d5
  223.     rts
  224.  
  225. DrawRadioButton:
  226.     movem.l a2-a4/a6/d2-d7,-(sp)
  227.  
  228.     move.l db_GfxBase(a6),a6
  229.     move.l a0,a2
  230.     move.l d0,d6
  231.     move.l d1,d7
  232.  
  233.     move.l a2,a1
  234.     move.l d4,d0
  235.     jsr _LVOSetAPen(a6)
  236.  
  237.     move.l a2,a1
  238.     move.l d6,d0
  239.     move.l d0,a3
  240.     move.l d7,d1
  241.     subq.l #1,d1
  242.     move.l d1,a4
  243.     jsr _LVOMove(a6)
  244.  
  245.     move.l a2,a1
  246.     move.l d6,d0
  247.     add.l d2,d0
  248.     addq.l #1,d0
  249.     move.l a4,d1
  250.     subq.l #2,d1
  251.     jsr _LVODraw(a6)
  252.  
  253.     move.l a2,a1
  254.     move.l a3,d0
  255.     move.l a4,d1
  256.     jsr _LVOMove(a6)
  257.  
  258.     move.l a2,a1
  259.     move.l a3,d0
  260.     move.l d7,d1
  261.     add.l d3,d1
  262.     jsr _LVODraw(a6)
  263.  
  264.     move.l a2,a1
  265.     move.l d6,d0
  266.     subq.l #1,d0
  267.     move.l d0,a3
  268.     move.l a4,d1
  269.     jsr _LVOMove(a6)
  270.  
  271.     move.l a2,a1
  272.     move.l a3,d0
  273.     move.l d7,d1
  274.     add.l d3,d1
  275.     move.l d1,a4
  276.     subq.l #1,d1
  277.     jsr _LVODraw(a6)
  278.  
  279.     move.l a2,a1
  280.     move.l d5,d0
  281.     jsr _LVOSetAPen(a6)
  282.  
  283.     move.l a2,a1
  284.     move.l a3,d0
  285.     move.l a4,d1
  286.     jsr _LVOMove(a6)
  287.  
  288.     move.l a2,a1    
  289.     move.l d6,d0
  290.     add.l d2,d0
  291.     move.l d0,a3
  292.     addq.l #1,d0
  293.     move.l a4,d1
  294.     jsr _LVODraw(a6)
  295.  
  296.     move.l a2,a1
  297.     move.l a3,d0
  298.     addq.l #1,d0
  299.     move.l d7,d1
  300.     subq.l #1,d1
  301.     jsr _LVODraw(a6)
  302.  
  303.     move.l a2,a1
  304.     move.l a3,d0
  305.     move.l a4,d1
  306.     jsr _LVOMove(a6)
  307.  
  308.     move.l a2,a1
  309.     move.l a3,d0
  310.     move.l d7,d1
  311.     jsr _LVODraw(a6)
  312.  
  313.     movem.l (sp)+,a2-a4/a6/d2-d7
  314.     rts
  315.  
  316. _SwapMem:
  317.     move.b (a0),d1
  318.     move.b (a1),(a0)+
  319.     move.b d1,(a1)+
  320.     subq.l #1,d0
  321.     bne.s _SwapMem
  322.     rts
  323.  
  324. _LSprintf:
  325. LSprintf:
  326.     movem.l a2/a3/a6,-(sp)
  327.     move.l 4*4(sp),a3
  328.     move.l 5*4(sp),a0
  329.     lea.l 6*4(sp),a1
  330.     lea.l stuffChar(pc),a2
  331.     move.l 4,a6
  332.     jsr _LVORawDoFmt(a6)
  333.     movem.l (sp)+,a2/a3/a6
  334.     rts
  335.  
  336. stuffChar:
  337.     move.b d0,(a3)+
  338.     rts
  339.  
  340. LCreateExtIO:
  341.     movem.l a6/d2/d3,-(sp)
  342.     move.l a0,d2
  343.     moveq.l #0,d3
  344.     move.w d0,d3
  345.     beq.s endextio
  346.     move.l #196608,d1
  347.     move.l 4,a6
  348.     jsr _LVOAllocMem(a6)
  349.     tst.l d0
  350.     beq.s endextio
  351.     move.l d0,a0
  352.     move.b #NT_MESSAGE,LN_TYPE(a0)
  353.     move.w d3,MN_LENGTH(a0)
  354.     move.l d2,MN_REPLYPORT(a0)
  355.     move.l a0,d0
  356.     movem.l (sp)+,a6/d2/d3
  357.     rts
  358. endextio:
  359.     movem.l (sp)+,a6/d2/d3
  360.     moveq.l #0,d0
  361.     rts
  362.  
  363. LCreatePort:
  364.     movem.l a2/a3/a6/d2/d3,-(sp)
  365.     move.l a0,a2
  366.     move.l d0,d2
  367.     move.l #-1,d0
  368.     move.l 4,a6
  369.     jsr _LVOAllocSignal(a6)
  370.     cmp.b #-1,d0
  371.     beq endport
  372.     move.b d0,d3
  373.     move.l #MP_SIZE,d0
  374.     move.l #196608,d1
  375.     move.l 4,a6
  376.     jsr _LVOAllocMem(a6)
  377.     tst.l d0
  378.     beq.s endport1
  379.     move.l d0,a3
  380.     move.l a2,LN_NAME(a3)
  381.     move.b d2,LN_PRI(a3)
  382.     move.b #NT_MSGPORT,LN_TYPE(a3)
  383.     move.b #PA_SIGNAL,MP_FLAGS(a3)
  384.     move.b d3,MP_SIGBIT(a3)
  385.     move.l #0,a1
  386.     move.l 4,a6
  387.     jsr _LVOFindTask(a6)
  388.     move.l d0,MP_SIGTASK(a3)
  389.     cmp.l #0,a2
  390.     beq.s noname
  391.     move.l a3,a1
  392.     move.l 4,a6
  393.     jsr _LVOAddPort(a6)
  394.     bra.s endgotport
  395. noname:
  396.     lea MP_MSGLIST(a3),a0
  397.     move.l a0,LH_HEAD(a0)
  398.     addq.l #4,LH_HEAD(a0)
  399.     clr.l LH_TAIL(a0)
  400.     move.l a0,LH_TAILPRED(a0)
  401. endgotport:
  402.     move.l a3,d0
  403.     movem.l (sp)+,a2/a3/a6/d2/d3
  404.     rts
  405. endport1:
  406.     move.l 4,a6
  407.     jsr _LVOFreeSignal(a6)
  408. endport:
  409.     movem.l (sp)+,a2/a3/a6/d2/d3
  410.     rts
  411.  
  412. LDeleteExtIO:
  413.     move.l a6,-(sp)
  414.     move.b #-1,LN_TYPE(a0)
  415.     move.l #-1,MN_REPLYPORT(a0)
  416.     move.l #-1,IO_DEVICE(a0)
  417.     move.l a0,a1
  418.     moveq.l #0,d0
  419.     move.w MN_LENGTH(a0),d0
  420.     move.l 4,a6
  421.     jsr _LVOFreeMem(a6)
  422.     move.l (sp)+,a6
  423.     rts
  424.  
  425. LDeletePort:
  426.     movem.l a2/a6,-(sp)
  427.     move.l a0,a2
  428.     move.l LN_NAME(a2),d0
  429.     tst.l d0
  430.     beq.s nonamefree
  431.     move.l a0,a1
  432.     move.l 4,a6
  433.     jsr _LVORemPort(a6)
  434. nonamefree:
  435.     move.l #-1,MP_SIGTASK(a2)
  436.     lea MP_MSGLIST(a2),a0
  437.     move.l #-1,LH_HEAD(a0)
  438.     moveq.l #0,d0
  439.     move.b MP_SIGBIT(a2),d0
  440.     move.l 4,a6
  441.     jsr _LVOFreeSignal(a6)
  442.     move.l a2,a1
  443.     move.l #MP_SIZE,d0
  444.     move.l 4,a6
  445.     jsr _LVOFreeMem(a6)
  446.     movem.l (sp)+,a2/a6
  447.     rts
  448.  
  449. LToUpper:
  450.     cmp.b #'a'-1,d0
  451.     bls tu_done
  452.     cmp.b #'z',d0
  453.     bhi tu_done
  454.     sub.b #'a'-'A',d0
  455. tu_done:
  456.     rts
  457.  
  458. LToLower:
  459.     cmp.b #'A'-1,d0
  460.     bls tl_done
  461.     cmp.b #'Z',d0
  462.     bhi tl_done
  463.     add.b #'a'-'A',d0
  464. tl_done:
  465.     rts
  466.  
  467. LStrCat:
  468.     move.l #$ffff,d0
  469. LStrnCat:
  470.     tst.b (a0)+
  471.     bne.s    LStrnCat
  472.     sub.l #1,a0
  473.     subq.l #1,d0
  474. catloop:
  475.     move.b (a1)+,(a0)+
  476.     dbeq d0,catloop
  477.     beq.s endcat
  478.     clr.b (a0)
  479. endcat:
  480.     rts
  481.  
  482. LStrCpy:
  483.     move.b (a1)+,(a0)+
  484.     bne.s    LStrCpy
  485.     rts
  486.  
  487. LStrnCpy:
  488.     move.b (a1)+,(a0)+
  489.     beq.s endstrncpy
  490.     dbeq d0,LStrnCpy
  491.     move.b #0,-(a0)
  492. endstrncpy:
  493.     rts
  494.  
  495. LStrCmpI:
  496.     move.l #$7fff,d0
  497. LStrnCmpI:
  498.     move.l d2,-(sp)
  499.     move.l d0,d2
  500.     subq.l #1,d2
  501.     bmi equal
  502. cmploop:
  503.     move.b (a0)+,d0
  504.     ext.l d0
  505.     bsr LToUpper
  506.     move.b d0,d1
  507.     move.b (a1)+,d0
  508.     ext.l d0
  509.     bsr LToUpper
  510.     cmp.b d0,d1
  511.     blt less
  512.     bgt greater
  513.     tst.b d1
  514.     dbeq d2,cmploop
  515. equal:
  516.     moveq.l #0,d0
  517.     move.l (sp)+,d2
  518.     rts
  519. greater:
  520.     moveq.l #1,d0
  521.     move.l (sp)+,d2
  522.     rts
  523. less:
  524.     move.l #-1,d0
  525.     move.l (sp)+,d2
  526.     rts
  527.  
  528. LStrCmp:
  529.     move.l #$7fff,d0
  530. LStrnCmp:
  531.     subq.l #1,d0
  532.     bmi equal1
  533.     moveq.l #0,d1
  534. cmploop1:
  535.     move.b (a0)+,d1
  536.     cmp.b (a1)+,d1
  537.     blt less1
  538.     bgt greater1
  539.     tst.b d1
  540.     dbeq d0,cmploop1
  541. equal1:
  542.     moveq.l #0,d0
  543.     rts
  544. greater1:
  545.     moveq.l #1,d0
  546.     rts
  547. less1:
  548.     move.l #-1,d0
  549.     rts
  550.  
  551. endcode:
  552.     END
  553.